Thank you for your kind words!
I have written a few prototypes
and it seems to work fine.

I like that it allows me to
use inline styles and
decompose my application into
small components, e.g.

proc render-panel {name body} {
	html div style {
		display: flex;
		flex-direction: column;
		gap: 2rem;
		padding: 2rem;
		border-radius: 1rem;
		background-color: #fafaf9;
	} {
		html strong text $name
		uplevel 1 $body
	}
}

Here a little trick is used:
I do not like to write 0.25rem
or 0.5rem all the time, so I set
the font-size of html to 25% and
and the font-size of body to 400%.
so 1rem is actually 0.25em.

If you want to try it, here is a Version
that writes to the wapp .reply string:


proc html {tag args} {
	global wapp

	# Normalize Implicit Script
	if {[llength $args] % 2 == 1} {
		set args [linsert $args end-1 body]
	}

	# Generate Attributes String
	set attributes {}
	foreach {name value} $args {
		switch $name {
			{html} {}
			{text} {}
			{body} {}
			{default} {
				# Collapse Whitespace
				set value [regsub -all {\s+} $value { }]
				# Escape Quotes
				set value [string map {\" "} $value]
				# Trim Whitespace
				set value [string trim $value]
				# Skip Empty Attributes
				if {$value == {}} {
					continue
				}
				# Append Attribute
				set attributes [format {%s %s="%s"} $attributes $name $value]
			}
		}
	}

	# Append Opening Tag
	switch $tag {
		{} {}
		{default} {
			# Maybe Append Newline
			switch [string index [dict get $wapp .reply] end] {
				{} {}
				\n {}
				default {
					dict append wapp .reply \n
				}
			}
			# Append the actual Tag
			dict append wapp .reply <$tag$attributes>
		}
	}
	# Process Special Attributes
	foreach {name value} $args {
		switch $name {
			{html} { dict append wapp .reply $value }
			{text} { dict append wapp .reply [string map {< &lt;} $value] }
			{body} { uplevel 1 $value }
		}
	}
	# Append Closing Tag
	switch $tag {
		{} {}
		{area} {}
		{base} {}
		{br} {}
		{col} {}
		{embed} {}
		{hr} {}
		{img} {}
		{input} {}
		{link} {}
		{meta} {}
		{param} {}
		{source} {}
		{track} {}
		{wbr} {}
		{default} {
			dict append wapp .reply </$tag>\n
		}
	}
}

Thank you for your kind words.  I apologize
for my late reply, I did not forget you.
It's just that my queue is full.

You can call the proc olaf if you want to.
But I prefer the name html.  I created a
repository on github:

  https://github.com/oruppert/html.tcl

I added some of your changes there and
will add your name in the comments if
that is fine with you.

Thank you for your link to the tcl wiki.
I will write a page in the next week
or so.  Would you want me to include
some tricks I learned writing dumb old
webpages?  Sometimes I have the feeling
people have forgotten how to write
html based web applications, like this
forum: Simple, fast, useful.

Take care, Olaf